Описание:

MP3 модуль DFPlayer mini позволяет воспроизводить MP3 записи со встроенной карты памяти, как при помощи Ардуино, так и самостоятельно. Модуль оснащен встроенным усилителем мощности, поэтому нет необходиости использовать дополнительный усилитель, а можно сразу подключить динамик.
Для удобства работы есть библиотека, которую можно скачать и использовать для работы с Ардуино.

Характеристики:

• поддерживаемые частоты дискретизации (кГц): 8 / 11,025 / 12/16 / 22.05 / 24/32 / 44.1 / 48
• 24-битный ЦАП, поддержка динамического диапазона 90 дБ, поддержка SNR 85 дБ
• полностью поддерживает файловую систему FAT16, FAT32, максимальную поддержку 32G TF-карты, поддержку 32G U-диска, 64M байт NORFLASH
• различные режимы управления, режим управления вводом / выводом, последовательный режим, режим управления кнопками AD
• функция звукового ожидания рекламы, музыка может быть приостановлена на время воспроизведения рекламы. После окончания воспроизведения рекламы, музыка продолжит воспроизведение
• Поддержка до 100 папок с музыкой. Каждая пака может содержать до 255 трэков.
• 30 уровней регулировки звука, 6-уровневый эквалайзер

Подключение к Ардуино осуществляется по схеме:



Для работы без контроллера можно использовать кнопки управления, подключенные через резисторы, согластно таблице ниже:

#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"

SoftwareSerial mySoftwareSerial(10, 11); // RX, TX
DFRobotDFPlayerMini myDFPlayer;
void printDetail(uint8_t type, int value);

void setup()
{
  mySoftwareSerial.begin(9600);
  Serial.begin(115200);
  
  Serial.println();
  Serial.println(F("DFRobot DFPlayer Mini Demo"));
  Serial.println(F("Initializing DFPlayer ... (May take 3~5 seconds)"));
  
  if (!myDFPlayer.begin(mySoftwareSerial)) {  //Use softwareSerial to communicate with mp3.
    Serial.println(F("Unable to begin:"));
    Serial.println(F("1.Please recheck the connection!"));
    Serial.println(F("2.Please insert the SD card!"));
    while(true);
  }
  Serial.println(F("DFPlayer Mini online."));
  
  myDFPlayer.volume(10);  //Set volume value. From 0 to 30
  myDFPlayer.play(1);  //Play the first mp3
}

void loop()
{
  static unsigned long timer = millis();
  
  if (millis() - timer > 3000) {
    timer = millis();
    myDFPlayer.next();  //Play next mp3 every 3 second.
  }
  
  if (myDFPlayer.available()) {
    printDetail(myDFPlayer.readType(), myDFPlayer.read()); //Print the detail message from DFPlayer to handle different errors and states.
  }
}

void printDetail(uint8_t type, int value){
  switch (type) {
    case TimeOut:
      Serial.println(F("Time Out!"));
      break;
    case WrongStack:
      Serial.println(F("Stack Wrong!"));
      break;
    case DFPlayerCardInserted:
      Serial.println(F("Card Inserted!"));
      break;
    case DFPlayerCardRemoved:
      Serial.println(F("Card Removed!"));
      break;
    case DFPlayerCardOnline:
      Serial.println(F("Card Online!"));
      break;
    case DFPlayerPlayFinished:
      Serial.print(F("Number:"));
      Serial.print(value);
      Serial.println(F(" Play Finished!"));
      break;
    case DFPlayerError:
      Serial.print(F("DFPlayerError:"));
      switch (value) {
        case Busy:
          Serial.println(F("Card not found"));
          break;
        case Sleeping:
          Serial.println(F("Sleeping"));
          break;
        case SerialWrongStack:
          Serial.println(F("Get Wrong Stack"));
          break;
        case CheckSumNotMatch:
          Serial.println(F("Check Sum Not Match"));
          break;
        case FileIndexOut:
          Serial.println(F("File Index Out of Bound"));
          break;
        case FileMismatch:
          Serial.println(F("Cannot Find File"));
          break;
        case Advertise:
          Serial.println(F("In Advertise"));
          break;
        default:
          break;
      }
      break;
    default:
      break;
  }
}